大家好，這里是程序員杰克。一名平平無奇的嵌入式軟件工程師。

上兩篇已經總結和分享了RGB接口TFT-LCD觸摸屏的相關內容。 本篇使用Verilog語言實現RGB的驅動時序。

前面描述了很多關于時序的內容，但其實在FPGA中實現RGB接口的LCD屏驅動時序還是很簡單的。 只需要實現行掃描、列掃描的時鐘周期控制，并且在有效區域輸出對應像素點的RGB數據便可。 實現控制時序和測試驗證難度不大，主要還是要在實際的項目中應用，例如：實時顯示攝像頭的圖像信息等。 由于文字篇幅原因， 本篇僅對RGB接口驅動時序的實現思想以及Verilog語言代碼進行說明。

下面正式進入本章推送的內容。

01 時序參數

常用的TFT-LCD屏(幀率為60Hz)時序參數如下圖所示，其中，行同步信號時序的單位是時鐘脈沖，而場同步信號時序的單位是行周期。

對于驅動時序而言，最重要的是確定幀率和像素時鐘，其他參數由廠商提供。本示例使用的是分辨率為800*480 的4.3寸TFT-LCD屏，使用的幀率為60Hz(每秒60幀圖像)，時序參參數以及相關計算公式如下表所示：

02 時序實現

對于幀率和分辨率固定的LCD屏幕驅動時序(RGB接口)，有以下特點：

• 圖像輸出的行掃描、列掃描是周期性的邏輯
• 同步時序(SYNC)、有效信號(DE)的脈沖固定

設計思路

FPGA設計周期性的時序，可以通過計數器來控制，在計數器的對應count數執行相對應的邏輯； 對于邏輯而言，需要考慮的是同步信號、數據有效信號的范圍脈沖數、以及掃描周期； 行掃描、列掃描對應的設計思路如下(800*480 @60 TFT-LCD屏示例)：

行掃描時序實現

由于FPGA設計計數器時，一般從0開始計數，因此行掃描邏輯控制參數需要減去1，如下表所示：

Verilog實現代碼如下：

parameter  H_SYNC        = 11'd127    ;
parameter  H_DATA_START  = 11'd215    ;
parameter  H_DATA_END    = 11'd1015   ;
parameter  H_PERIOD      = 11'd1055   ;
//行掃描控制時序
reg  [10:0]  h_cnt;
always @(posedge pclk) begin
  if(rst_n == 1'b0) begin
    h_cnt  <= 11'd0;
  end
  else if(h_cnt == H_PERIOD) begin
    h_cnt  <= 11'd0;
  end
  else begin
    h_cnt  <= h_cnt + 1'b1;
  end
end
assign hsync  = (h_cnt > H_SYNC) ? 1'b1 : 1'b0;
assign h_index = (h_cnt > H_DATA_START) ? (h_cnt - H_DATA_START) : 11'd0;

場掃描時序實現

由于FPGA設計計數器時，一般從0開始計數，因此行掃描邏輯控制參數需要減去1，如下表所示：

Verilog實現代碼如下：

parameter  v_SYNC        = 11'd1    ;
parameter  v_DATA_START  = 11'd34   ;
parameter  v_DATA_END    = 11'd514  ;
parameter  v_PERIOD      = 11'd524  ;
//場掃描控制時序
reg  [10:0]  v_cnt;
always @(posedge pclk) begin
  if(rst_n == 1'b0) begin
    v_cnt  <= 11'd0;
  end
  else if(v_cnt == v_PERIOD) begin
    v_cnt  <= 11'd0;
  end
  else if(h_cnt == H_PERIOD) begin
    v_cnt  <= v_cnt + 1'b1;
  end
  else begin
    v_cnt  <= v_cnt;
  end
end
assign vsync  = (v_cnt > v_SYNC) ? 1'b1 : 1'b0;
assign v_index  = (v_cnt > v_DATA_START) ? (v_cnt - v_DATA_START) : 11'd0;

完整Verilog代碼如下：

module parallel_rgb_control
#
(
  parameter  H_SYNC        = 11'd127   ,
  parameter  H_DATA_START  = 11'd215   ,
  parameter  H_DATA_END    = 11'd1015  ,
  parameter  H_PERIOD      = 11'd1055  ,


  parameter  v_SYNC        = 11'd1    ,
  parameter  v_DATA_START  = 11'd34   ,
  parameter  v_DATA_END    = 11'd514  ,
  parameter  v_PERIOD      = 11'd524  
)
(
  input    wire        pclk    ,
  input    wire        rst_n    ,

  output  wire          hsync    ,
  output  wire  [10:0]  h_index  ,

  output  wire          vsync    ,
  output  wire  [10:0]  v_index  ,

  output  wire        de      
);


//行掃描控制時序
reg  [10:0]  h_cnt;
always @(posedge pclk) begin
  if(rst_n == 1'b0) begin
    h_cnt  <= 11'd0;
  end
  else if(h_cnt == H_PERIOD) begin
    h_cnt  <= 11'd0;
  end
  else begin
    h_cnt  <= h_cnt + 1'b1;
  end
end
assign hsync  = (h_cnt > H_SYNC) ? 1'b1 : 1'b0;
assign h_index = (h_cnt > H_DATA_START) ? (h_cnt - H_DATA_START) : 11'd0;


//場掃描控制時序
reg  [10:0]  v_cnt;
always @(posedge pclk) begin
  if(rst_n == 1'b0) begin
    v_cnt  <= 11'd0;
  end
  else if(v_cnt == v_PERIOD) begin
    v_cnt  <= 11'd0;
  end
  else if(h_cnt == H_PERIOD) begin
    v_cnt  <= v_cnt + 1'b1;
  end
  else begin
    v_cnt  <= v_cnt;
  end
end
assign vsync  = (v_cnt > v_SYNC) ? 1'b1 : 1'b0;
assign v_index  = (v_cnt > v_DATA_START) ? (v_cnt - v_DATA_START) : 11'd0;
assign de = ( (h_cnt >= H_DATA_START) && (h_cnt < H_DATA_END) ) && ( (v_cnt >= v_DATA_START) && (v_cnt < v_DATA_END) );
endmodule

05 文章總結

對于RGB接口的TFT-LCD屏的時序驅動代碼還是較為簡單的。 使用文字描述實際的應用并且讓人容易理解，還是很困難的。 基于此，本篇僅僅只是分享了RGB接口周期時序的實現，對于具體的數據輸出顯示的應用并未說明。 倘若有兄弟想了解實際應用，可以添加杰克的微信號來交流。