描述

我們都知道，在你的生活中沒有那個(gè)特別的人可能會(huì)很困難，但是如果你可以通過互聯(lián)網(wǎng)遠(yuǎn)程發(fā)送愛和感情，只需擁抱一個(gè)枕頭呢？現(xiàn)在，我們不能真正發(fā)送擁抱……但我們可以通過消息應(yīng)用程序發(fā)送一個(gè)甜蜜的表情符號(hào)，由你給枕頭一個(gè)擁抱觸發(fā)。當(dāng)你擁抱我愛你枕頭時(shí)，你會(huì)聽到里面的蜂鳴器發(fā)出心跳的聲音。根據(jù)您擁抱的長度，Telegram Bot 將向您選擇的任何聊天發(fā)送不同的表情符號(hào)。使用這款可擁抱的設(shè)備與您所愛的人保持聯(lián)系！

簡而言之

在這個(gè)實(shí)驗(yàn)中，我們將使用鋁箔制作一個(gè) DIY 電容傳感器，用于檢測擁抱。為了創(chuàng)建我們的擁抱發(fā)送設(shè)備，我們需要以下組件：

• 蜂鳴器

• 鋁箔

• 1個(gè)電阻5M歐姆

• 面包板

• 電線

學(xué)習(xí)目標(biāo)

• 介紹電報(bào)機(jī)器人

• 管理電容式傳感器

• 電報(bào)機(jī)器人和群聊#ProTips

• WiFi 最佳實(shí)踐#ProTips

專業(yè)提示是有用但并非絕對(duì)必要的步驟，它們會(huì)為項(xiàng)目增加一層復(fù)雜性。

想知道更多？

本教程是讓您熟悉 MKR WiFi 1010 和 IoT 的一系列實(shí)驗(yàn)的一部分。所有實(shí)驗(yàn)都可以使用 MKR IoT Bundle 中包含的組件構(gòu)建。

• 我愛你枕頭與 MKR WiFi 1010

• 帶 MKR WiFi 1010 的益智盒

• 巴甫洛夫的貓與 MKR WiFi 1010

• 使用 MKR WiFi 1010 的書呆子

• 帶有 MKR WiFi 1010 的植物通訊器

介紹電報(bào)機(jī)器人

Telegram是一款流行的移動(dòng)和桌面消息傳遞應(yīng)用程序。除了讓我們與朋友聊天之外，它還允許我們創(chuàng)建方便且強(qiáng)大的聊天機(jī)器人！

聊天機(jī)器人只不過是您可以與之聊天的聯(lián)系人，而是它背后的人，有一臺(tái)機(jī)器可以相應(yīng)地回復(fù)您編寫的代碼。

Arduino的 TelegramBot 庫為我們提供了一種簡單的方法來實(shí)現(xiàn)聊天機(jī)器人背后的邏輯。

創(chuàng)建你的機(jī)器人

創(chuàng)建一個(gè)機(jī)器人是如此簡單！只需按照這幾個(gè)簡單的步驟或在此處查看文檔。

?

?

?

?

?

1 / 5 ?第 1 步 - 尋找 BotFather

?

設(shè)置董事會(huì)

首先確保我們擁有所有需要的庫。這是我們需要的所有庫的列表：

• WiFi妮娜

• 電報(bào)機(jī)器人

• ArduinoJson

• 電容式傳感器

您可以按照這個(gè)簡單的指南輕松安裝它們。

為了使用 Telegram 的 API，我們首先需要在 MKR WiFi 1010 上上傳證書。這適用于大多數(shù)在線服務(wù)和 API！

從 WiFiNINA 庫上傳固件更新程序示例并將 api.telegram.org 添加到域。這些是要遵循的步驟：

• 運(yùn)行IDE；

• 上傳草圖`Example->WiFiNINA->tools->Firmware updater`

• 在工具中打開`WiFi101/WiFiNINA 固件更新程序`

• 點(diǎn)擊“添加域”

• 添加 https://api.telegram.org

• 單擊“將證書上傳到 WiFi 模塊”

• 上傳你的草圖`

讓魔法發(fā)生！

打開 TelegramBot 庫中的 EchoBot 示例，填寫您的 WiFi 憑據(jù)和您從 BotFather 收到的 API 令牌并上傳！

> 示例 > TelegramBot > EchoBot

您剛剛創(chuàng)建了一個(gè)回顯所有消息的機(jī)器人。

EchoBot 和表情符號(hào)

表情符號(hào)無處不在！我們將用它們來傳遞我們的愛和擁抱。使用 EchoBot 示例是查看機(jī)器人如何讀取您的表情符號(hào)的簡單方法。

?

向 Bot 發(fā)送表情符號(hào)，看看編碼后的等價(jià)物是什么

?

不幸的是，機(jī)器人接收表情符號(hào)的方式與發(fā)送它們的方式不同。為了發(fā)送表情符號(hào)，我們需要使用UNICODE字符。

例如，要發(fā)送一個(gè)心形表情符號(hào)，我們將使用： \U00002764

您可以在此處查看unicode 表情符號(hào)代碼的完整列表。為了創(chuàng)建一個(gè)用另一個(gè)心臟表情符號(hào)回復(fù)心臟表情符號(hào)的機(jī)器人，我們將使用如下代碼：

void loop() {
 message m = bot.getUpdates(); // Read new messages
 if ( m.chat_id != 0 ) { // Check if there are some updates
   Serial.println(m.text); // print the message received
   if (m.text == "u2764ufe0f") { //check if it received an heart emoji
     bot.sendMessage(m.chat_id, "\U00002764");
     // Reply to the same chat with the heart emoji
   }
 }
}

結(jié)果將是：

?

用另一個(gè)心形表情符號(hào)回復(fù)心形表情符號(hào)

?

電容式傳感器

Telegram 夠了，讓我們開始構(gòu)建我們的 DIY 電容式傳感器吧！

CapacitiveSensor庫將兩個(gè)或多個(gè) Arduino 引腳變成一個(gè)電容傳感器，可以感應(yīng)人體的電容。

傳感器設(shè)置所需的只是一個(gè)中值到高值的電阻器和一塊鋁箔。

在最敏感的情況下，傳感器將開始感應(yīng)距離傳感器幾英寸的手或身體，并通過不同種類的材料。我們將把傳感器藏在枕頭里！

上傳示例草圖，連接電線并在控制臺(tái)上查看結(jié)果：

#include 
CapacitiveSensor   foil = CapacitiveSensor(5, 4);
// 10M resistor between pins 5 & 4, pin 4 is sensor pin, add a wire and or foil
void setup()
{
 foil.set_CS_AutocaL_Millis(0xFFFFFFFF);     // turn off autocalibrate
 Serial.begin(9600);
}
void loop()
{
 long start = millis();
 long sensor_value =  foil.capacitiveSensor(30);
 Serial.print(millis() - start);        // check on performance in milliseconds
 Serial.print("\t");                    // tab character for debug windown spacing
 Serial.print(sensor_value);            // print sensor output
 Serial.println("\t");                    // print sensor output 3
 delay(500);                             // arbitrary delay to limit data to serial port
}

接線和結(jié)果

?

在控制臺(tái)上查看值

?

我們將sensor_value用作檢測擁抱的閾值！

心跳

擁抱的時(shí)間越長，聽到的心跳聲就越多。心跳越多，您發(fā)送的愛就越多（以及不同的表情符號(hào)）。

我們將使用蜂鳴器和幾行簡單的代碼來模擬心跳的聲音。

int Buzzer = 8; // Pin attached to the buzzer
void setup() {}
void loop() {
 HeartBeat();
 delay(1000);
}
void HeartBeat() {
 tone(Buzzer, 31, 200); // tone(Pin, Note, Duration);
 delay(200);
 tone(Buzzer, 31, 400);
 delay(200);
 noTone(Buzzer);
 delay(1000);
} 

要更復(fù)雜地使用蜂鳴器和音調(diào)功能，請查看下拉菜單示例并查找 Digital > ToneMelody

#ProTip：聊天 ID 和群聊

為了發(fā)送消息，機(jī)器人需要一個(gè)聊天 ID。聊天 id 是某人和機(jī)器人之間聊天的唯一標(biāo)識(shí)符。為了讓機(jī)器人向特定的人發(fā)送消息，您首先需要該人向機(jī)器人發(fā)送短信并保存該特定聊天的聊天 ID。

在這個(gè)項(xiàng)目中，機(jī)器人只會(huì)回復(fù)最后一個(gè)發(fā)短信的人，不管那是誰。

機(jī)器人是公開的，每個(gè)人都可以給機(jī)器人發(fā)短信！

如果您想將機(jī)器人包含在群聊中，您需要禁用隱私模式以允許機(jī)器人閱讀所有消息，否則它將只能檢測以開頭的命令/:

?

?

?

?

?

1 / 3 ?使用 /mybot 命令向@BotFather 發(fā)送文本，然后選擇您的機(jī)器人和機(jī)器人設(shè)置

?

#ProTip：WiFi 最佳實(shí)踐

WiFi 可能很棘手。有時(shí)它只是關(guān)閉幾秒鐘，顯然沒有任何理由。這對(duì)您的 Arduino 來說可能是個(gè)問題，因?yàn)榇蠖鄶?shù)時(shí)候我們只在草圖的開頭運(yùn)行 WiFi 連接功能。

在線服務(wù)也可能很棘手，當(dāng) Arduino 向服務(wù)器（在本例中為 Telegram）發(fā)送請求時(shí)，它會(huì)等待回復(fù)。由于數(shù)百個(gè)原因，回復(fù)可能無法到達(dá)，使 Arduino 處于無限循環(huán)中。

為了讓你的項(xiàng)目更穩(wěn)定，你可以添加一個(gè)看門狗。看門狗是一個(gè)必須定期更新的計(jì)時(shí)器，否則它將重新啟動(dòng)電路板。

您可以使用這兩個(gè)庫向您的項(xiàng)目添加看門狗：

• Adafruit SleepyDog

• Adafruit ASF Core // 必須從 Github 手動(dòng)下載和安裝

EchoBot 示例將如下所示：

#include <WiFi101.h>
#include <SPI.h>
#include <TelegramBot.h>
#include <Adafruit_SleepyDog.h>
// Initialize Wifi connection to the router
char ssid[] = "xxxx";             // your network SSID (name)
char pass[] = "yyyy";           // your network key
// Initialize Telegram BOT
const char BotToken[] = "xxxx";
WiFiSSLClient client;
TelegramBot bot (BotToken, client);
void setup() {
 Serial.begin(115200);
 while (!Serial) {}
 delay(3000);
 // attempt to connect to Wifi network:
 Serial.print("Connecting Wifi: ");
 Serial.println(ssid);
 while (WiFi.begin(ssid, pass) != WL_CONNECTED) {
   Serial.print(".");
   delay(500);
 }
 Serial.println("");
 Serial.println("WiFi connected");
 bot.begin();
 Watchdog.enable(10000); // set the timer to 10 sec
}
void loop() {
 Watchdog.reset(); // if this function is not called within 10 seconds the board will reset itself
 message m = bot.getUpdates(); // Read new messages
 if ( m.chat_id != 0 ) { // Checks if there are some updates
   Serial.println(m.text);
   bot.sendMessage(m.chat_id, m.text);  // Reply to the same chat with the same text
 } else {
   Serial.println("no new message");
 }
}